[转]一个简单的python socket编程

2008年09月07日作者: KingFo 开发者

原文：http://hi.baidu.com/pplboy/blog/item/c29a4dd45b8d0507a08bb7e7.html

python 编写server的步骤：

第一步是创建socket对象。调用socket构造函数。如：
```
socket = socket.socket( family, type ) 
```
family参数代表地址家族，可为AF_INET或AF_UNIX。AF_INET家族包括Internet地址，AF_UNIX家族用于同一台机器上的进程间通信。
type参数代表套接字类型，可为SOCK_STREAM(流套接字)和SOCK_DGRAM(数据报套接字)。
第二步是将socket绑定到指定地址。这是通过socket对象的bind方法来实现的：
```
socket.bind( address )  
```
由AF_INET所创建的套接字，address地址必须是一个双元素元组，格式是(host,port)。host代表主机，port代表端口号。如果端口号正在使用、主机名不正确或端口已被保留，bind方法将引发socket.error异常。
第三步是使用socket套接字的listen方法接收连接请求。
```
socket.listen( backlog ) 
```
backlog指定最多允许多少个客户连接到服务器。它的值至少为1。收到连接请求后，这些请求需要排队，如果队列满，就拒绝请求。
第四步是服务器套接字通过socket的accept方法等待客户请求一个连接。
```
connection, address = socket.accept() 
```
调用accept方法时，socket会时入“waiting”状态。客户请求连接时，方法建立连接并返回服务器。accept方法返回一个含有两个元素的元组(connection,address)。第一个元素connection是新的socket对象，服务器必须通过它与客户通信；第二个元素 address是客户的Internet地址。
第五步是处理阶段，服务器和客户端通过send和recv方法通信(传输数据)。服务器调用send，并采用字符串形式向客户发送信息。send方法返回已发送的字符个数。服务器使用recv方法从客户接收信息。调用recv 时，服务器必须指定一个整数，它对应于可通过本次方法调用来接收的最大数据量。recv方法在接收数据时会进入“blocked”状态，最后返回一个字符串，用它表示收到的数据。如果发送的数据量超过了recv所允许的，数据会被截短。多余的数据将缓冲于接收端。以后调用recv时，多余的数据会从缓冲区删除(以及自上次调用recv以来，客户可能发送的其它任何数据)。
传输结束，服务器调用socket的close方法关闭连接。

python编写client的步骤：

创建一个socket以连接服务器：socket = socket.socket( family, type )
使用socket的connect方法连接服务器。对于AF_INET家族,连接格式如下：
```
socket.connect( (host,port) ) 
```
host代表服务器主机名或IP，port代表服务器进程所绑定的端口号。如连接成功，客户就可通过套接字与服务器通信，如果连接失败，会引发socket.error异常。
处理阶段，客户和服务器将通过send方法和recv方法通信。
传输结束，客户通过调用socket的close方法关闭连接。

下面给个简单的例子：

server.py

python 代码

if __name__ == '__main__':     
    import socket     
     sock = socket.socket(socket.AF_INET, socket.SOCK_STREAM)     
     sock.bind(('localhost', 8001))     
     sock.listen(5)     
    while True:     
         connection,address = sock.accept()     
        try:     
             connection.settimeout(5)     
             buf = connection.recv(1024)     
            if buf == '1':     
                 connection.send('welcome to server!')     
            else:     
                 connection.send('please go out!')     
        except socket.timeout:     
            print 'time out'     
         connection.close()

client.py

python 代码

if __name__ == '__main__':     
    import socket     
     sock = socket.socket(socket.AF_INET, socket.SOCK_STREAM)     
     sock.connect(('localhost', 8001))     
    import time     
    time.sleep(2)     
     sock.send('1')     
    print sock.recv(1024)     
     sock.close()

在终端运行server.py，然后运行clien.py，会在终端打印“welcome to server!"。如果更改client.py的sock.send('1')为其它值在终端会打印”please go out!“，更改time.sleep(2)为大于5的数值，服务器将会超时。

被阅 359 次, 0 票　　发表评论

code My-X-Intend

[原]关于AS3的MovieClip的addFrameScript()方法个人理解

2008年09月04日作者: KingFo 原创

网络上都早有了此方法的描述，但是描述的并不太在正确
网络的描述是这样的：

addFrameScript(frame:unit,notify:Function):void;

相信很多人都尝试过以下输出公共方法的函数

describeType();

所以通过解析可以明显的看出来是类似：

addFrameScript(...args):void;

可以理解成为：

addFrameScript(frame:Object, notify:Function):void;

实际上我的猜测是

//伪码  
function addFrameScript(..args):void{  
    var i:int=0;  
    var frame:Object  
    var notify::Function  
    for(;i<args.length;i+=2){  
       frame=args[i];  
       notify=args[i+1];
        //TODO:  
 }  
 
}

用法:

addFrameScript("frameLabel",func);  
//或  
addFrameScript(1,func);

被阅 417 次, 0 票　　发表评论

My-X-Intend 原创||心得 Adobe-Front-End-Technology code

[原]动态注册点显示对象 AS3实现---Proxy方法

2008年08月26日作者: KingFo 原创

由于之前的

动态注册点显示对象 AS3实现

不太适合多类型的显示对象DisplayObject复合应用，因此实际应用过程中采用了Proxy模式，这样

只要注册时使用对应的显示对象即可。

PS: 由于Blog限制，示例不能再摘要中显示，故请点击文章内部看玩具吧.....

示例：
操作：单击确定旋转/缩放点，按下并拖动鼠标则实现以旋转，鼠标滚轮则缩放对应的点。

点击下载此文件

源码：

package  com.xintend.util {  
    import flash.display.DisplayObject;  
    import flash.display.Sprite;  
    import flash.geom.Point;  
    import flash.utils.Proxy;  
    import flash.utils.flash_proxy;  
 
      
    /**  
    * [AS3]DynamicRegistrationProxy  
    * 动态注册点代理   引用请保留此处信息及参考信息  
    * @author telds[kingfo] www.xintend.com   
    *   
    *   
    * 一级参考:  
    *   作者： Darronschall        [ActionScript 2]  
    *   站点: http://www.darronschall.com/weblog/archives/000054.cfm  
    *   
    * 二级参考:  
    *   作者:     Robert Penner       [ActionScript 1]  
    *   站点: www.robertpenner.com      
    *   
    */ 
    public dynamic class DynamicRegistrationProxy extends Proxy {         
          
        public function DynamicRegistrationProxy(source:DisplayObject=null):void {  
            _displayObject = source || new Sprite();  
        }  
          
        override flash_proxy function callProperty(methodName:*, ... args):*  {  
            var res:*;  
            var a:Point;  
            var b:Point;  
            var method:String = methodName.toString();  
            var property:String;  
            switch (method) {  
                case 'setRegistrationByStage':  
                    a = _displayObject.globalToLocal(new Point(args[0], args[1]));                    
                    _stageRegX = args[0];  
                    _stageRegY = args[1];         
                    _regX = a.x;  
                    _regY = a.y;  
                break;  
                case 'setRegistrationBySelf':  
                    a = _displayObject.localToGlobal(new Point(args[0], args[1]));                    
                    _regX = args[0];  
                    _regY = args[1];          
                    _stageRegX = a.x;  
                    _stageRegY = a.y;  
                break;  
                case 'setPropRel':  
                    a = _displayObject.parent.globalToLocal(_displayObject.localToGlobal(new Point(_regX, _regY)));  
                    property = args[0].toString();  
                    _displayObject[property] = args[1];           
                    b = _displayObject.parent.globalToLocal(_displayObject.localToGlobal(new Point(_regX, _regY)));       
                    _displayObject.x -= b.x - a.x;  
                    _displayObject.y -= b.y - a.y;  
                break;                
                default:  
                    res = _displayObject[method].apply(_displayObject, args);  
                break;  
            }  
            return res;  
        }  
          
        override flash_proxy function getProperty(name:*):* {  
            var res:*;  
            var property:String = name.toString();  
            switch (property) {  
                case 'regX':  
                    res = _regX;  
                break;  
                case 'regY':  
                    res = _regY;  
                break;  
                case 'stageRegX':  
                    res = _stageRegX;  
                break;  
                case 'stageRegY':  
                    res = _stageRegY;  
                break;  
                case 'x2':  
                    res = _x2;  
                break;  
                case 'y2':  
                    res = _y2;  
                break;  
                case 'scaleX2':  
                    res = _displayObject.scaleX;  
                break;  
                case 'scaleY2':  
                    res = _displayObject.scaleY;  
                break;  
                case 'rotation2':  
                    res = _displayObject.rotation  
                break;  
                case 'source':  
                    res = _displayObject;  
                break;  
                default:  
                    res = _displayObject[property];  
                break;  
            }  
            return res;  
        }  
 
        override flash_proxy function setProperty(name:*, value:*):void {  
            var property:String = name.toString();            
            switch (property) {  
                case 'regX':  
                    _regX = value;  
                break;  
                case 'regY':  
                    _regY = value;  
                break;  
                case 'stageRegX':  
                    _stageRegX = value;  
                break;  
                case 'stageRegY':  
                    _stageRegY = value;  
                break;  
                case 'x2':  
                    _x2 += value - _displayObject.x;  
                break;  
                case 'y2':  
                    _y2 += value - _displayObject.y;  
                break;  
                case 'scaleX2':  
                    flash_proxy::callProperty('setPropRel',"scaleX", value);  
                break;  
                case 'scaleY2':  
                    flash_proxy::callProperty('setPropRel',"scaleY", value);  
                break;  
                case 'rotation2':  
                    flash_proxy::callProperty('setPropRel',"rotation", value);  
                break;  
                default:  
                    _displayObject[property] = value;  
                    break;  
            }  
        }  
 
          
          
        private var  _displayObject:DisplayObject;  
        private var _regX:Number = 0;  
        private var _regY:Number = 0;  
        private var _stageRegX:Number = 0;  
        private var _stageRegY:Number = 0;  
        private var _x2:Number = 0;  
        private var _y2:Number = 0;  
    }  
      
}

示例源码：

package {  
      
    import com.xintend.util.DynamicRegistrationProxy;  
    import flash.display.Bitmap;  
    import flash.display.Sprite;  
    import flash.events.MouseEvent;  
    import flash.geom.Point;  
      
    public class Main extends Sprite    {  
          
        private var a:DynamicRegistrationProxy;  
        private var t:Sprite = new Sprite();  
        private var c:CrossHairs = new CrossHairs();  
        [Embed(source = '../bin/123.jpg')]private var imge:Class;  
        private var b:Bitmap  
        public function Main():void {  
              
            b=new imge() as Bitmap  
              
            //t.graphics.beginFill(0xFF0000);  
            //t.graphics.drawRect(0, 0, 80, 40);  
            //t.graphics.endFill();  
              
            //t.buttonMode = true;  
            //t.useHandCursor = true;  
              
            t.addChild(b);  
            c.x = t.x = stage.stageWidth / 2- t.width/2;  
            c.y = t.y = stage.stageHeight / 2 - t.height/2;  
              
              
            t.addEventListener(MouseEvent.MOUSE_DOWN, handleMOUSE);  
            t.addEventListener(MouseEvent.MOUSE_OUT, handleMOUSE);  
            t.addEventListener(MouseEvent.MOUSE_WHEEL, handleMOUSE);  
              
            a = new DynamicRegistrationProxy(t);  
              
            addChild(t);  
            addChild(c);  
        }  
          
        private  function handleMOUSE(event:MouseEvent):void {  
            switch(event.type) {  
                case MouseEvent.MOUSE_DOWN:  
                    a.setRegistrationByStage(mouseX, mouseY);  
                    //trace(t.globalToLocal(new Point(mouseX,0)).x,t.globalToLocal(new Point(0,mouseY)).y);  
                    c.x = mouseX;  
                    c.y = mouseY;  
                    removeEventListener(MouseEvent.MOUSE_DOWN, handleMOUSE);  
                    addEventListener(MouseEvent.MOUSE_MOVE, handleMOUSE);  
                    addEventListener(MouseEvent.MOUSE_UP, handleMOUSE);  
                break;  
                case MouseEvent.MOUSE_MOVE:  
                    //trace(t.mouseX - a.regX, t.mouseY - a.regY);  
                    a.rotation2 += 5;  
                    //a.scaleXByRefer += 5;  
                break;  
                case MouseEvent.MOUSE_UP:     
                    addEventListener(MouseEvent.MOUSE_DOWN, handleMOUSE);  
                    removeEventListener(MouseEvent.MOUSE_MOVE, handleMOUSE);  
                break;  
                case MouseEvent.MOUSE_WHEEL:      
                    removeEventListener(MouseEvent.MOUSE_MOVE, handleMOUSE);  
                    c.x = mouseX;  
                    c.y = mouseY  
                    a.setRegistrationByStage(mouseX, mouseY);  
                    a.scaleX2 += event.delta * 0.1;  
                    a.scaleY2 += event.delta * 0.1;  
                break;  
                default:  
                    addEventListener(MouseEvent.MOUSE_DOWN, handleMOUSE);  
                    removeEventListener(MouseEvent.MOUSE_MOVE, handleMOUSE);  
            }  
        }  
    }  
}  
import flash.display.Shape;  
 
class CrossHairs extends Shape {  
    public function CrossHairs() {  
        graphics.lineStyle(2,0xFF0000);  
        graphics.moveTo( -10, 0);  
        graphics.lineTo( 10, 0);  
        graphics.moveTo( 0, -10);  
        graphics.lineTo( 0, 10);  
    }  
}