这里公布答案:

getDefinitionByName()  它将直接从当前应用程序域(ApplicationDomain)去查询并获取，因此当我们Load，一个swf执行时，会报错。

有时候对于多层次的应用程序域（相当于应用程序域的树，层次>=3）管理起来会非常麻烦。

因此我们需要单独提取出LoaderContext 管理他们，通过LoaderContext的applicationDomain中getDefinition()来管理它们。例如 单例模式。

道理弄懂了，实现起来就是很简单的东西了。

当然，这里随机的方式不做讨论，可以参阅之前本人的 48位线性同余算法的 [原]关于股子系统的优化

完整代码:
 

package  {  
    import flash.utils.getDefinitionByName;  
      
    /**  
     * ...  
     * @author Telds[KingFo]  
     */ 
    public class SampleImage {  
          
        [Embed(source = '../assets/building/image0.png')]public static const BUILDING_0:Class;  
        [Embed(source = '../assets/building/image1.png')]public static const BUILDING_1:Class;  
        [Embed(source = '../assets/building/image2.png')]public static const BUILDING_2:Class;  
        [Embed(source = '../assets/building/image3.png')]public static const BUILDING_3:Class;  
        [Embed(source = '../assets/building/image4.png')]public static const BUILDING_4:Class;  
        [Embed(source = '../assets/building/image5.png')]public static const BUILDING_5:Class;  
        [Embed(source = '../assets/building/image6.png')]public static const BUILDING_6:Class;  
        [Embed(source = '../assets/building/image7.png')]public static const BUILDING_7:Class;  
        [Embed(source = '../assets/building/image8.png')]public static const BUILDING_8:Class;  
        [Embed(source = '../assets/building/image9.png')]public static const BUILDING_9:Class;  
        [Embed(source = '../assets/building/image10.png')]public static const BUILDING_10:Class;  
        [Embed(source = '../assets/building/image11.png')]public static const BUILDING_11:Class;  
        [Embed(source = '../assets/building/image12.png')]public static const BUILDING_12:Class;  
          
        public static function getRandomImageClass():Class {  
            var n:String = "SampleImage_BUILDING_";  
            var i:int = Math.random() * 12;  
            n = n.concat(i);  
            return getDefinitionByName(n) as Class;  
        }  
          
    }  
      
} 

至于如何知道完全限定类名

可以使用以下类进行测试获取，这里值得一提的是我上面的写法是比较特殊例子，至于为什么特殊就留着看客您琢磨了~~~
 

flash.utils.getQualifiedClassName ()  

已完成数据解码和校验~~~~ 不过目前还是体力活~~~

接下来是还原图片。。。。。。哎，周末结束了.............真不知道我下次有时间是什么时候了。。

以下是测试代码，工程截图............. 哦 对了，这个所谓的 1455049.png就是前篇博文：APNG?
中插入图片，我之所以写这段解码器目的其实只是想让IE也能预览APNG而已........哎.....
不知道哪位同学有APNG解码器的代码呢？有的话可以告诉我声哦~~~

public function Main():void {  
            var l:URLLoader = new URLLoader();  
            l.dataFormat = URLLoaderDataFormat.BINARY;  
            l.addEventListener(Event.COMPLETE, handleURLloader);  
            l.load(new URLRequest("../image/1455049.png"));  
            }  
          
        private function handleURLloader(e:Event):void {  
            apngdecoder.decode(e.target.data)  
            trace(apngdecoder.getResult().getTotalFrames())  
            trace(apngdecoder.getResult().getWidth())  
            trace(apngdecoder.getResult().getWidth())  
            trace(apngdecoder.getResult().getBitDepth())  
              
                          
        } 

本人的类:

package  {  
    import flash.utils.ByteArray;  
      
    /**  
     * CRC 32位 校验类  
     * 与JAVA的CRC32类似  
     * 算法参考自 as3corelib http://code.google.com/p/as3corelib/    
     * 的 PNGEncoder.as 中CRC算法部分  
     * @author Telds[KingFo]  
     * @version 0.0.1  
     * @example  
     * var bytes:ByteArray = new ByteArray();  
     * var crc32:CRC32 = new CRC32();  
     * var str:String="kingfo";  
     * bytes.writeUTFBytes(str);  
     * crc32.update(bytes);  
     * trace(crc32);  
     */ 
    public class CRC32 {  
        public static const POLYNOMIAL:uint = 0xEDB88320;  
        /**  
         * 创建获取CRC表  
         * @return  
         */ 
        public static function getCrcTable():Array {  
            /* Make the table for a fast CRC. */ 
            if (!crcTableComputed) {  
                crcTable = new Array(256);  
                var c:uint;  
                for (var i:uint=0; i < 256; i++) {  
                    c = i;  
                    for (var j:uint=0; j < 8; j++) {  
                        c = (c & 1) ? (c >>> 1) ^ POLYNOMIAL : (c >>> 1);  
                    }  
                    crcTable[i] = c;  
                }  
                crcTableComputed = true;  
            }             
            return crcTable;  
        }  
        /**  
         * 构造函数，实例化同时产生CRC表  
         */ 
        public function CRC32() {  
            getCrcTable();  
        }         
        /**  
         * 更新CRC  
         * @param   bytes                   指定更新的字节流  
         * @param   offset                  偏移量，默认从 bytes.position=0 开始  
         * @param   length                  长度,默认为0，即指定更新的字节流的长度          
         */ 
        public function update(bytes:ByteArray, offset:int=0,length:int=0):void {  
            length = length > 0 ? length : bytes.length;  
            var c:uint = ~value;  
            for (var i:int = offset; i < length; i++) {  
                c = crcTable[(c ^ bytes[i]) & 0xFF] ^ (c >>> 8);  
            }  
            value = ~c;  
        }  
        /**  
         * 获取结果  
         * @return  
         */ 
        public function getValue():uint {  
            return value & 0xFFFFFFFF;  
        }  
        /**  
         * 重置结果  
         */ 
        public function reset():void {  
            value = 0x00000000;  
        }  
          
        public function toString():String {  
            var v:uint = getValue();  
            return "0x"+v.toString(16).toUpperCase();  
        }  
          
          
 
        private var value:uint = 0x00000000;          
        /* Table of CRCs of all 8-bit messages. */ 
        private static var crcTable:Array;  
        /* Flag: has the table been computed? Initially false. */ 
        private static var crcTableComputed:Boolean = false;  
          
          
    }  
      
} 

PNGEncoder.as 中CRC 核心代码部分:
 

if (!crcTableComputed) {  
            crcTableComputed = true;  
            crcTable = [];  
            var c:uint;  
            for (var n:uint = 0; n < 256; n++) {  
                c = n;  
                for (var k:uint = 0; k < 8; k++) {  
                    if (c & 1) {  
                        c = uint(uint(0xedb88320) ^   
                            uint(c >>> 1));  
                    } else {  
                        c = uint(c >>> 1);  
                    }  
                }  
                crcTable[n] = c;  
            }  
        }  
/////  
c = 0xffffffff;  
        for (var i:int = 0; i < (e-p); i++) {  
            c = uint(crcTable[  
                (c ^ png.readUnsignedByte()) &   
                uint(0xff)] ^ uint(c >>> 8));  
        }  
        c = uint(c^uint(0xffffffff)); 

Sample Cyclic Redundancy Code implementation
 

/* Table of CRCs of all 8-bit messages. */ 
   unsigned long crc_table[256];  
     
   /* Flag: has the table been computed? Initially false. */ 
   int crc_table_computed = 0;  
     
   /* Make the table for a fast CRC. */ 
   void make_crc_table(void)  
   {  
     unsigned long c;  
     int n, k;  
     
     for (n = 0; n < 256; n++) {  
       c = (unsigned long) n;  
       for (k = 0; k < 8; k++) {  
         if (c & 1)  
           c = 0xedb88320L ^ (c >> 1);  
         else 
           c = c >> 1;  
       }  
       crc_table[n] = c;  
     }  
     crc_table_computed = 1;  
   }  
    
 
   /* Update a running CRC with the bytes buf[0..len-1]--the CRC  
      should be initialized to all 1's, and the transmitted value  
      is the 1's complement of the final running CRC (see the  
      crc() routine below). */ 
     
   unsigned long update_crc(unsigned long crc, unsigned char *buf,  
                            int len)  
   {  
     unsigned long c = crc;  
     int n;  
     
     if (!crc_table_computed)  
       make_crc_table();  
     for (n = 0; n < len; n++) {  
       c = crc_table[(c ^ buf[n]) & 0xff] ^ (c >> 8);  
     }  
     return c;  
   }  
     
   /* Return the CRC of the bytes buf[0..len-1]. */ 
   unsigned long crc(unsigned char *buf, int len)  
   {  
     return update_crc(0xffffffffL, buf, len) ^ 0xffffffffL;  
   }  
 

果然是无法Draw的，在帮助文档已经明确的写了......................................

如何突破呢？ 还是以后直接拿TextField来用？

以此标记，下回，改用AVM1+AVM2混合内容测试

目前方法是猥琐的抽出Loader来用

测试连接：
www.xintend.com/temp/icd/index.html

有兴趣的同学可以去玩下~~ 图片可以拖动~~~~~~~

核心 代码部分:
 

 function handleLoadBtn():void {  
            var s:String = urlInput.text;  
            var ht:String = "<img src='";  
            if (s.length > 0) {  
                ht += s;                                  
                ht += "' ";  
                ht += "id='image'>";  
                tf.htmlText = ht;  
                output.text = ht;  
                output.text += "\n";                  
                output.text += tf.getImageReference("image");  
                var c:DisplayObject = tf.getImageReference("image");  
                ui.addChild(c);  
                output.text += "\n ui.addChild(c);";  
            }  
        } 

本次纠正模型如下(点击图片看大图)：
还是需要等待时间和实践的验证~~~

不过，有些郁闷的是开店需要用到的图片，淘宝发布商品是不支持上传的，于是找了N多家

虽然最终被我找到了几个免费的图片供应站，但是仍然觉得很不爽，毕竟静态图片要表现的内容也算是比较小的。

于是，我本着万愚之精神，开始设想，如果taobao不提供上传，那至少可以提供一个图片的播放器给用户....不过，由于flash player有安全沙箱问题，无法装载外站图片，但不知道类似扒来的图片连接能不能用......或者，干脆用AVM1机制下的一些猥琐方法？？ 没玩过......有谁知道可以告诉我下~~~~，厄，要不HtmlText纯载如图片映射？？？ 哎，不猜测了，这几日测试看看好了~~~

好吧，土人的设想是这么一副图片，主要是供给店主使用的，放在商品介绍上..... 这个成本应该比视频类的滴了吧............这样店主就应该很容易的展示自己的商品了，客户也容易逛到一个店后在一个窗口下所谓的无刷新搜索其他产品和比较产品以及欣赏产品了吧,(这句话我承认有点长了~~就委屈您囧一下吧~~)

好，来图土一土~~~ 超级打算嘛~~~

由于笔记本或多网卡联网机器的原因，所以我们需要判断被系统选择使用的网卡，因此，需要在原文中的判断处获取所选择DNS列表来判断是否正在使用。

不知道还有什么更好的办法，本方法也是一种判断的方式：

以下为完全HTML源码：
(相关API请参考: http://www.xintend.com/Article/QFFrUjDCBWYWzjoBinNT.aspx )

<HTML><HEAD><TITLE>WMI Scripting HTML</TITLE> 
<META http-equiv=Content-Type content="text/html; charset=gb2312"> 
<SCRIPT language=JScript event="OnCompleted(hResult,pErrorObject, pAsyncContext)" for=foo> 
document.forms[0].txtMACAddr.value=unescape(MACAddr);  
document.forms[0].txtIPAddr.value=unescape(IPAddr);  
document.forms[0].txtDNSName.value=unescape(sDNSName);  
 
  </SCRIPT> 
 
<SCRIPT language=JScript event=OnObjectReady(objObject,objAsyncContext) for=foo> 
   if(objObject.IPEnabled != null && objObject.IPEnabled != "undefined" && objObject.IPEnabled == true)  
    {  
    if(objObject.MACAddress != null && objObject.MACAddress != "undefined" && objObject.DNSServerSearchOrder!=null)  
     MACAddr = objObject.MACAddress;  
    if(objObject.IPEnabled && objObject.IPAddress(0) != null && objObject.IPAddress(0) != "undefined" && objObject.DNSServerSearchOrder!=null)  
     IPAddr = objObject.IPAddress(0);  
    if(objObject.DNSHostName != null && objObject.DNSHostName != "undefined")  
     sDNSName = objObject.DNSHostName;  
     }  
  </SCRIPT> 
 
<META content="MSHTML 6.00.2800.1106" name=GENERATOR></HEAD> 
<BODY> 
<OBJECT id=locator classid=CLSID:76A64158-CB41-11D1-8B02-00600806D9B6 VIEWASTEXT></OBJECT> 
<OBJECT id=foo classid=CLSID:75718C9A-F029-11d1-A1AC-00C04FB6C223></OBJECT> 
<SCRIPT language=JScript> 
   var service = locator.ConnectServer();  
   var MACAddr ;  
   var IPAddr ;  
   var DomainAddr;  
   var sDNSName;  
    service.Security_.ImpersonationLevel=3;  
    service.InstancesOfAsync(foo, 'Win32_NetworkAdapterConfiguration');  
   </SCRIPT> 
 
<FORM id="formfoo" name="formbar" action="index.do" method="post"><INPUT value="00-11-11-B4-52-EF" name="txtMACAddr"> <INPUT value="210.42.38.50" name="txtIPAddr"> <INPUT value="zhupan" name="txtDNSName"> </FORM></BODY></HTML> 

addFrameScript(frame:unit,notify:Function):void; 

相信很多人都尝试过以下输出公共方法的函数
 

describeType(); 

所以通过解析可以明显的看出来是类似：
 

addFrameScript(...args):void; 

可以理解成为：
 

addFrameScript(frame:Object, notify:Function):void; 

实际上我的猜测是

//伪码  
function addFrameScript(..args):void{  
    var i:int=0;  
    var frame:Object  
    var notify::Function  
    for(;i<args.length;i+=2){  
       frame=args[i];  
       notify=args[i+1];
        //TODO:  
 }  
 
} 

 用法:
 

addFrameScript("frameLabel",func);  
//或  
addFrameScript(1,func); 

动态注册点显示对象 AS3实现

源码：
 

package  com.xintend.util {  
    import flash.display.DisplayObject;  
    import flash.display.Sprite;  
    import flash.geom.Point;  
    import flash.utils.Proxy;  
    import flash.utils.flash_proxy;  
 
      
    /**  
    * [AS3]DynamicRegistrationProxy  
    * 动态注册点代理   引用请保留此处信息及参考信息  
    * @author telds[kingfo] www.xintend.com   
    *   
    *   
    * 一级参考:  
    *   作者： Darronschall        [ActionScript 2]  
    *   站点: http://www.darronschall.com/weblog/archives/000054.cfm  
    *   
    * 二级参考:  
    *   作者:     Robert Penner       [ActionScript 1]  
    *   站点: www.robertpenner.com      
    *   
    */ 
    public dynamic class DynamicRegistrationProxy extends Proxy {         
          
        public function DynamicRegistrationProxy(source:DisplayObject=null):void {  
            _displayObject = source || new Sprite();  
        }  
          
        override flash_proxy function callProperty(methodName:*, ... args):*  {  
            var res:*;  
            var a:Point;  
            var b:Point;  
            var method:String = methodName.toString();  
            var property:String;  
            switch (method) {  
                case 'setRegistrationByStage':  
                    a = _displayObject.globalToLocal(new Point(args[0], args[1]));                    
                    _stageRegX = args[0];  
                    _stageRegY = args[1];         
                    _regX = a.x;  
                    _regY = a.y;  
                break;  
                case 'setRegistrationBySelf':  
                    a = _displayObject.localToGlobal(new Point(args[0], args[1]));                    
                    _regX = args[0];  
                    _regY = args[1];          
                    _stageRegX = a.x;  
                    _stageRegY = a.y;  
                break;  
                case 'setPropRel':  
                    a = _displayObject.parent.globalToLocal(_displayObject.localToGlobal(new Point(_regX, _regY)));  
                    property = args[0].toString();  
                    _displayObject[property] = args[1];           
                    b = _displayObject.parent.globalToLocal(_displayObject.localToGlobal(new Point(_regX, _regY)));       
                    _displayObject.x -= b.x - a.x;  
                    _displayObject.y -= b.y - a.y;  
                break;                
                default:  
                    res = _displayObject[method].apply(_displayObject, args);  
                break;  
            }  
            return res;  
        }  
          
        override flash_proxy function getProperty(name:*):* {  
            var res:*;  
            var property:String = name.toString();  
            switch (property) {  
                case 'regX':  
                    res = _regX;  
                break;  
                case 'regY':  
                    res = _regY;  
                break;  
                case 'stageRegX':  
                    res = _stageRegX;  
                break;  
                case 'stageRegY':  
                    res = _stageRegY;  
                break;  
                case 'x2':  
                    res = _x2;  
                break;  
                case 'y2':  
                    res = _y2;  
                break;  
                case 'scaleX2':  
                    res = _displayObject.scaleX;  
                break;  
                case 'scaleY2':  
                    res = _displayObject.scaleY;  
                break;  
                case 'rotation2':  
                    res = _displayObject.rotation  
                break;  
                case 'source':  
                    res = _displayObject;  
                break;  
                default:  
                    res = _displayObject[property];  
                break;  
            }  
            return res;  
        }  
 
        override flash_proxy function setProperty(name:*, value:*):void {  
            var property:String = name.toString();            
            switch (property) {  
                case 'regX':  
                    _regX = value;  
                break;  
                case 'regY':  
                    _regY = value;  
                break;  
                case 'stageRegX':  
                    _stageRegX = value;  
                break;  
                case 'stageRegY':  
                    _stageRegY = value;  
                break;  
                case 'x2':  
                    _x2 += value - _displayObject.x;  
                break;  
                case 'y2':  
                    _y2 += value - _displayObject.y;  
                break;  
                case 'scaleX2':  
                    flash_proxy::callProperty('setPropRel',"scaleX", value);  
                break;  
                case 'scaleY2':  
                    flash_proxy::callProperty('setPropRel',"scaleY", value);  
                break;  
                case 'rotation2':  
                    flash_proxy::callProperty('setPropRel',"rotation", value);  
                break;  
                default:  
                    _displayObject[property] = value;  
                    break;  
            }  
        }  
 
          
          
        private var  _displayObject:DisplayObject;  
        private var _regX:Number = 0;  
        private var _regY:Number = 0;  
        private var _stageRegX:Number = 0;  
        private var _stageRegY:Number = 0;  
        private var _x2:Number = 0;  
        private var _y2:Number = 0;  
    }  
      
} 

示例源码：
 

package {  
      
    import com.xintend.util.DynamicRegistrationProxy;  
    import flash.display.Bitmap;  
    import flash.display.Sprite;  
    import flash.events.MouseEvent;  
    import flash.geom.Point;  
      
    public class Main extends Sprite    {  
          
        private var a:DynamicRegistrationProxy;  
        private var t:Sprite = new Sprite();  
        private var c:CrossHairs = new CrossHairs();  
        [Embed(source = '../bin/123.jpg')]private var imge:Class;  
        private var b:Bitmap  
        public function Main():void {  
              
            b=new imge() as Bitmap  
              
            //t.graphics.beginFill(0xFF0000);  
            //t.graphics.drawRect(0, 0, 80, 40);  
            //t.graphics.endFill();  
              
            //t.buttonMode = true;  
            //t.useHandCursor = true;  
              
            t.addChild(b);  
            c.x = t.x = stage.stageWidth / 2- t.width/2;  
            c.y = t.y = stage.stageHeight / 2 - t.height/2;  
              
              
            t.addEventListener(MouseEvent.MOUSE_DOWN, handleMOUSE);  
            t.addEventListener(MouseEvent.MOUSE_OUT, handleMOUSE);  
            t.addEventListener(MouseEvent.MOUSE_WHEEL, handleMOUSE);  
              
            a = new DynamicRegistrationProxy(t);  
              
            addChild(t);  
            addChild(c);  
        }  
          
        private  function handleMOUSE(event:MouseEvent):void {  
            switch(event.type) {  
                case MouseEvent.MOUSE_DOWN:  
                    a.setRegistrationByStage(mouseX, mouseY);  
                    //trace(t.globalToLocal(new Point(mouseX,0)).x,t.globalToLocal(new Point(0,mouseY)).y);  
                    c.x = mouseX;  
                    c.y = mouseY;  
                    removeEventListener(MouseEvent.MOUSE_DOWN, handleMOUSE);  
                    addEventListener(MouseEvent.MOUSE_MOVE, handleMOUSE);  
                    addEventListener(MouseEvent.MOUSE_UP, handleMOUSE);  
                break;  
                case MouseEvent.MOUSE_MOVE:  
                    //trace(t.mouseX - a.regX, t.mouseY - a.regY);  
                    a.rotation2 += 5;  
                    //a.scaleXByRefer += 5;  
                break;  
                case MouseEvent.MOUSE_UP:     
                    addEventListener(MouseEvent.MOUSE_DOWN, handleMOUSE);  
                    removeEventListener(MouseEvent.MOUSE_MOVE, handleMOUSE);  
                break;  
                case MouseEvent.MOUSE_WHEEL:      
                    removeEventListener(MouseEvent.MOUSE_MOVE, handleMOUSE);  
                    c.x = mouseX;  
                    c.y = mouseY  
                    a.setRegistrationByStage(mouseX, mouseY);  
                    a.scaleX2 += event.delta * 0.1;  
                    a.scaleY2 += event.delta * 0.1;  
                break;  
                default:  
                    addEventListener(MouseEvent.MOUSE_DOWN, handleMOUSE);  
                    removeEventListener(MouseEvent.MOUSE_MOVE, handleMOUSE);  
            }  
        }  
    }  
}  
import flash.display.Shape;  
 
class CrossHairs extends Shape {  
    public function CrossHairs() {  
        graphics.lineStyle(2,0xFF0000);  
        graphics.moveTo( -10, 0);  
        graphics.lineTo( 10, 0);  
        graphics.moveTo( 0, -10);  
        graphics.lineTo( 0, 10);  
    }  
}